Mostrando postagens com marcador VBScript. Mostrar todas as postagens

VBScript - Como criar atalho na área de trabalho

Caso você tenha a necessidade de criar um atalho na Área de Trabalho dos seus usuário em sua rede, vide como faz usando VBScript.

No exemplo abaixo, será criado um atalho na sua área de trabalho com o nome "Dicas Que Funfa". Esse atalho será aberto com o Internet Explorer que vai direto para o blog www.dicasquefunfa.com.br.

Set objShell = CreateObject("WScript.Shell")
strDesktop = objShell.SpecialFolders("Desktop")
Set objLink = objShell.CreateShortcut(strDesktop & "\DicasQueFunfa.lnk")
objLink.TargetPath = "C:\Program Files\Internet Explorer\iexplore.exe"
objLink.Arguments = "http://www.dicasquefunfa.com.br/"
objLink.WorkingDirectory = "%HOMEDRIVE%%HOMEPATH%"
objLink.IconLocation = "C:\Program Files\Internet Explorer\iexplore.exe, 2"
objLink.Description = "Dicas Que Funfa!"
objLink.Save

Para faze as alterações desejada, pasta mudar a parte em negrito.

Exemplo utilizado o Google Chrome

Set objShell = CreateObject("WScript.Shell")
strDesktop = objShell.SpecialFolders("Desktop")
Set objLink = objShell.CreateShortcut(strDesktop & "\DicasQueFunfa.lnk")
objLink.TargetPath = "C:\Program Files (x86)\Google\Chrome\Application\chrome.exe"
objLink.Arguments = "http://www.dicasquefunfa.com.br/"
objLink.WorkingDirectory = "%HOMEDRIVE%%HOMEPATH%"
objLink.IconLocation = "C:\Program Files (x86)\Google\Chrome\Application\chrome.exe, 2"
objLink.Description = "Dicas Que Funfa!"
objLink.Save

Um comentário:

Find out the manufacturer of your computer

On some computers does not come or deleted information such as make/model of your computer. With that you lose time when you need this information.
To resolve this problem, see the Script which tells the manufacturer, model and description from your computer.

To create this script follow the step listed below:

1. open Notepad
2. copy the code below, then paste into Notepad:


'==========================================================================
' LANGUAGE: VBScript '
' NAME: Info-PC version: 1.0
' AUTHOR: TIPS THAT FUNFA
' DATE: 12/22/2012
by: http://dicasquefunfa.com.br
'==========================================================================
strComputer = "."
Set objWMIService = GetObject ("winmgmts:" _
& "{impersonationLevel = impersonate}! \" & strComputer & "\root\cimv2")
Set objWMIService = colSoftware. _ ExecQuery
("Select * from Win32_ComputerSystem")

For Each objSoftware in colSoftware
WScript.echo "------------manufacturing Details-----------" & vbCrLf & _
"" & vbCrLf & _
"Computer manufacturer:" & objSoftware & vbCrLf & _ .manufacturer
"Type:" & objSoftware & vbCrLf & _ .model
"Description:" & objSoftware & vbCrLf & _ Description.
"Number of processors:" & objSoftware & vbCrLf & _ NumberOfProcessors.
"Type of system execution:" & objSoftware & vbCrLf SystemType.

Next

3. Save with the extension.VBS

Ready, that way whenever you need will have a practical and quick information for your computer. Nenhum comentário:

Descubra o Fabricante do seu computador

Em alguns computadores não vem ou apagou as informações como marca/modelo do seu computador. Com isso você perde tempo quando precisar dessas informações.
Para resolver esse problema de forma pratica, veja o Script que informa o fabricante, modelo e descrição do seu computador.
Para criar esse script siga o passo mencionados logo abaixo:

1. Abra o Bloco de Notas
2. Copie o código abaixo e em seguida cole no Bloco de Notas:


'==========================================================================
' LINGUAGEM: VBScript'
' NAME:  Info-PC VERSÃO: 1.0
' AUTHOR: DICAS QUE FUNFA
' DATE : 22/12/2012
' by: http://dicasquefunfa.com.br
'==========================================================================
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    Set colSoftware = objWMIService.ExecQuery _
    ("Select * from Win32_ComputerSystem")

    For Each objSoftware in colSoftware
    Wscript.Echo "------------ Detalhes de Fabricação -----------"& vbCrLf &_
    ""& vbCrLf &_
    "Fabricante do computador: " & objSoftware.Manufacturer & vbCrLf & _
    "Modelo: " & objSoftware.Model & vbCrLf & _
    "Descricao: " & objSoftware.Description & vbCrLf & _
    "Numero de Processadores: " & objSoftware.NumberOfProcessors & vbCrLf & _
    "Tipo de Sistema em execucao: " & objSoftware.SystemType & vbCrLf

    Next

3. Salve com a extensão .VBS

Pronto, dessa forma sempre que você precisar vai ter de forma pratica e rápido as informações do seu computador.  Nenhum comentário:

Listar todas as contas de computador no Active Directory



Descrição

Retorna o nome e local para todas as contas de computador no Active Directory.







Script Code


Const ADS_SCOPE_SUBTREE = 2

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCOmmand.ActiveConnection = objConnection
objCommand.CommandText = _
    "Select Name, Location from 'LDAP://DC=fabrikam,DC=com' " _
        & "Where objectClass='computer'"  
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
Set objRecordSet = objCommand.Execute
objRecordSet.MoveFirst

Do Until objRecordSet.EOF
    Wscript.Echo "Computer Name: " & objRecordSet.Fields("Name").Value
    Wscript.Echo "Location: " & objRecordSet.Fields("Location").Value
    objRecordSet.MoveNext
Loop

Fonte - Script Center
Version 3.0, November 2004 



Nenhum comentário:

Adicione um computador a um domínio

Descrição

Adiciona um computador local em um domínio e cria a conta do computador no Active Directory.







Script Code



Const JOIN_DOMAIN = 1
Const ACCT_CREATE = 2
Const ACCT_DELETE = 4
Const WIN9X_UPGRADE = 16
Const DOMAIN_JOIN_IF_JOINED = 32
Const JOIN_UNSECURE = 64
Const MACHINE_PASSWORD_PASSED = 128
Const DEFERRED_SPN_SET = 256
Const INSTALL_INVOCATION = 262144

strDomain = "FABRIKAM"
strPassword = "ls4k5ywA"
strUser = "shenalan"

Set objNetwork = CreateObject("WScript.Network")
strComputer = objNetwork.ComputerName

Set objComputer = GetObject("winmgmts:{impersonationLevel=Impersonate}!\\" & _
    strComputer & "\root\cimv2:Win32_ComputerSystem.Name='" & _
        strComputer & "'")

ReturnValue = objComputer.JoinDomainOrWorkGroup(strDomain, _
    strPassword, strDomain & "\" & strUser, NULL, _
        JOIN_DOMAIN + ACCT_CREATE)

Fonte - Script Center
Version 3.0, November 2004
Nenhum comentário:

Ativar um servidor de catálogo global


Descrição

Ativar um servidor de catálogo global no controlador de domínio atl-dc-01.








strComputer = "atl-dc-01"

Const NTDSDSA_OPT_IS_GC = 1

Set objRootDSE = GetObject("LDAP://" & strComputer & "/RootDSE")
strDsServiceDN = objRootDSE.Get("dsServiceName")
Set objDsRoot  = GetObject _
    ("LDAP://" & strComputer & "/" & strDsServiceDN)
intOptions = objDsRoot.Get("options")

If (intOptions And NTDSDSA_OPT_IS_GC) = FALSE Then
    objDsRoot.Put "options" , intOptions Or NTDSDSA_OPT_IS_GC
    objDsRoot.Setinfo
End If

Fonte - Script Center
Version 3.0, November 2004


Nenhum comentário:

Desativar um servidor de catálogo global


Descrição

Desativa o serviço de catálogo global no controlador de domínio atl-dc-01.








strComputer = "atl-dc-01"

Const NTDSDSA_OPT_IS_GC = 1

Set objRootDSE = GetObject("LDAP://" & strComputer & "/rootDSE")
strDsServiceDN = objRootDSE.Get("dsServiceName")
Set objDsRoot  = GetObject _
    ("LDAP://" & strComputer & "/" & strDsServiceDN)
intOptions = objDsRoot.Get("options")

If intOptions And NTDSDSA_OPT_IS_GC Then
    objDsRoot.Put "options", intOptions Xor NTDSDSA_OPT_IS_GC
    objDsRoot.Setinfo
End If

Fonte - Script Center
Version 3.0, November 2004

Nenhum comentário:

Excluir uma conta de computador


Descrição
Exclui uma conta de computador no Active Directory.










Script Code


strComputer = "atl-pro-040"

set objComputer = GetObject("LDAP://CN=" & strComputer & _
    ",CN=Computers,DC=fabrikam,DC=com")
objComputer.DeleteObject (0)

Fonte - Script Center
Version 3.0, November 2004

Nenhum comentário:

Crie uma conta de computador para um usuário específico


Descrição

Cria e habilita uma conta de computador no Active Directory. Um usuário específico, autenticado pode então usar essa conta para adicionar sua estação de trabalho ao domínio.






Script Code 


strComputer = "atl-pro-002"
strComputerUser = "fabrikam\lewjudy"

Const ADS_UF_PASSWD_NOTREQD = &h0020
Const ADS_UF_WORKSTATION_TRUST_ACCOUNT = &h1000
Const ADS_ACETYPE_ACCESS_ALLOWED = &h0
Const ADS_ACETYPE_ACCESS_ALLOWED_OBJECT = &h5
Const ADS_FLAG_OBJECT_TYPE_PRESENT = &h1
Const ADS_RIGHT_GENERIC_READ = &h80000000
Const ADS_RIGHT_DS_SELF = &h8
Const ADS_RIGHT_DS_WRITE_PROP = &h20
Const ADS_RIGHT_DS_CONTROL_ACCESS = &h100

Const ALLOWED_TO_AUTHENTICATE = _
    "{68B1D179-0D15-4d4f-AB71-46152E79A7BC}"
Const RECEIVE_AS = "{AB721A56-1E2f-11D0-9819-00AA0040529B}"
Const SEND_AS = "{AB721A54-1E2f-11D0-9819-00AA0040529B}"
Const USER_CHANGE_PASSWORD = _
    "{AB721A53-1E2f-11D0-9819-00AA0040529b}"
Const USER_FORCE_CHANGE_PASSWORD = _
    "{00299570-246D-11D0-A768-00AA006E0529}"
Const USER_ACCOUNT_RESTRICTIONS = _
    "{4C164200-20C0-11D0-A768-00AA006E0529}"
Const VALIDATED_DNS_HOST_NAME = _
    "{72E39547-7B18-11D1-ADEF-00C04FD8D5CD}"
Const VALIDATED_SPN = "{F3A64788-5306-11D1-A9C5-0000F80367C1}"

Set objRootDSE = GetObject("LDAP://rootDSE")
Set objContainer = GetObject("LDAP://cn=Computers," & _
    objRootDSE.Get("defaultNamingContext"))

Set objComputer = objContainer.Create _
    ("Computer", "cn=" & strComputer)
objComputer.Put "sAMAccountName", strComputer & "$"
objComputer.Put "userAccountControl", _
    ADS_UF_PASSWD_NOTREQD Or ADS_UF_WORKSTATION_TRUST_ACCOUNT
objComputer.SetInfo

Set objSecurityDescriptor = objComputer.Get("ntSecurityDescriptor")
Set objDACL = objSecurityDescriptor.DiscretionaryAcl

Set objACE1 = CreateObject("AccessControlEntry")
objACE1.Trustee    = strComputerUser
objACE1.AccessMask = ADS_RIGHT_GENERIC_READ
objACE1.AceFlags   = 0
objACE1.AceType    = ADS_ACETYPE_ACCESS_ALLOWED

Set objACE2 = CreateObject("AccessControlEntry")
objACE2.Trustee    = strComputerUser
objACE2.AccessMask = ADS_RIGHT_DS_CONTROL_ACCESS
objACE2.AceFlags   = 0
objACE2.AceType    = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE2.Flags      = ADS_FLAG_OBJECT_TYPE_PRESENT
objACE2.ObjectType = ALLOWED_TO_AUTHENTICATE

Set objACE3 = CreateObject("AccessControlEntry")
objACE3.Trustee    = strComputerUser
objACE3.AccessMask = ADS_RIGHT_DS_CONTROL_ACCESS
objACE3.AceFlags   = 0
objACE3.AceType    = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE3.Flags      = ADS_FLAG_OBJECT_TYPE_PRESENT
objACE3.ObjectType = RECEIVE_AS

Set objACE4 = CreateObject("AccessControlEntry")
objACE4.Trustee    = strComputerUser
objACE4.AccessMask = ADS_RIGHT_DS_CONTROL_ACCESS
objACE4.AceFlags   = 0
objACE4.AceType    = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE4.Flags      = ADS_FLAG_OBJECT_TYPE_PRESENT
objACE4.ObjectType = SEND_AS

Set objACE5 = CreateObject("AccessControlEntry")
objACE5.Trustee    = strComputerUser
objACE5.AccessMask = ADS_RIGHT_DS_CONTROL_ACCESS
objACE5.AceFlags   = 0
objACE5.AceType    = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE5.Flags      = ADS_FLAG_OBJECT_TYPE_PRESENT
objACE5.ObjectType = USER_CHANGE_PASSWORD

Set objACE6 = CreateObject("AccessControlEntry")
objACE6.Trustee    = strComputerUser
objACE6.AccessMask = ADS_RIGHT_DS_CONTROL_ACCESS
objACE6.AceFlags   = 0
objACE6.AceType    = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE6.Flags      = ADS_FLAG_OBJECT_TYPE_PRESENT
objACE6.ObjectType = USER_FORCE_CHANGE_PASSWORD

Set objACE7 = CreateObject("AccessControlEntry")
objACE7.Trustee    = strComputerUser
objACE7.AccessMask = ADS_RIGHT_DS_WRITE_PROP
objACE7.AceFlags   = 0
objACE7.AceType    = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE7.Flags      = ADS_FLAG_OBJECT_TYPE_PRESENT
objACE7.ObjectType = USER_ACCOUNT_RESTRICTIONS

Set objACE8 = CreateObject("AccessControlEntry")
objACE8.Trustee    = strComputerUser
objACE8.AccessMask = ADS_RIGHT_DS_SELF
objACE8.AceFlags   = 0
objACE8.AceType    = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE8.Flags      = ADS_FLAG_OBJECT_TYPE_PRESENT
objACE8.ObjectType = VALIDATED_DNS_HOST_NAME

Set objACE9 = CreateObject("AccessControlEntry")
objACE9.Trustee    = strComputerUser
objACE9.AccessMask = ADS_RIGHT_DS_SELF
objACE9.AceFlags   = 0
objACE9.AceType  = ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
objACE9.Flags  =  ADS_FLAG_OBJECT_TYPE_PRESENT
objACE9.ObjectType = VALIDATED_SPN

objDACL.AddAce objACE1
objDACL.AddAce objACE2
objDACL.AddAce objACE3
objDACL.AddAce objACE4
objDACL.AddAce objACE5
objDACL.AddAce objACE6
objDACL.AddAce objACE7
objDACL.AddAce objACE8
objDACL.AddAce objACE9

objSecurityDescriptor.DiscretionaryAcl = objDACL
objComputer.Put "ntSecurityDescriptor", objSecurityDescriptor
objComputer.SetInfo

Fonte - Script Center
Version 3.0, November 2004


Nenhum comentário:

Copiar uma conta de computador do Active Directory

Descrição
Recupera os atributos de um objeto de computador existente e copia os atributos para um novo objeto de computador criado pelo script.







Set objCompt = _
    GetObject("LDAP://cn=Computers,dc=NA,dc=fabrikam,dc=com")
Set objComptCopy = objCompt.Create("computer", "cn=SEA-SQL-01")
objComptCopy.Put "sAMAccountName", "sea-sql-01"
objComptCopy.SetInfo

Set objComptTemplate = GetObject _
    ("LDAP://cn=SEA-PM-01,cn=Computers,dc=NA,dc=fabrikam,dc=com")
arrAttributes = Array("description", "location")

For Each strAttrib in arrAttributes
    strValue = objComptTemplate.Get(strAttrib)
    objComptCopy.Put strAttrib, strValue
Next

objComptCopy.SetInfo



Fonte - Script Center
Version 3.0, November 2004

Nenhum comentário:

Audite as contas que foram adicionadas no grupo administradores

VBScript para auditar as contas que foram adicionadas no grupo administrador. Esse script ler o log de segurança do windows e em seguida informa quem foi adicionado no grupo administrador e quem adicionou. Essa consulta é realizada pelo ID de evento 636 para o Windows XP e o ID 4732 para o Windows7. O resultado é gerado em  um arquivo TXT salvo na pasta  "c:\LOG_SEG" na linha 35. Para conferir copie o código a baixo e cole no Notepad, em seguida salve como Nome.VBS



'==========================================================================
' LINGUAGEM: VBScript'
' NAME:  CABRUNCO - VERSÃO: 1.2
' AUTHOR: DICAS QUE FUNFA
' DATE : 00/08/2012
' by: http://dicasquefunfa.com.br
'==========================================================================
Option Explicit
'Menu----------------------------------------------
Dim objmenu, username, wshshell, fso
'--------------------------------------------------
Dim objFSO, objFolder, objFile, objWMI, objItem, objShell
Dim strComputer, strFileName, strFileOpen, strFolder, strPath
Dim intEvent, intNumberID, intRecordNum, colLoggedEvents
Dim intEventType, strLogType

Set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")

' --------------------------------------------------------
' Defini o nome da pasta e do arquivo
strComputer = InputBox("Digite o nome do computador", "CABRUNCO Caça as Bruxas e Não-Conformidades")
strFileName = "\Log_Seg.txt"
strFolder = "C:\LOG_SEG"
strPath = strFolder & strFileName
' -----------------------------------------------------
' Seção para criar a pasta e salvar o arquivo.
' Criar o File System Object
Set objFSO = CreateObject("Scripting.FileSystemObject")

' strFolder, Verifica se a pasta existe 
If objFSO.FolderExists(strFolder) Then
Set objFolder = objFSO.GetFolder(strFolder)
Else
Set objFolder = objFSO.CreateFolder(strFolder)
WScript.Echo "Pasta Criada Com Sucesso! " & strFolder
End If

If objFSO.FileExists(strFolder & strFileName) Then
Set objFolder = objFSO.GetFolder(strFolder)
Else
Set objFile = objFSO.CreateTextFile(strFolder & strFileName)
Wscript.Echo "Arquivo criado com Sucesso! " & strFolder & strFileName
End If 
' --------------------------------------------------
' Comandos vitais
set objFile = nothing
set objFolder = nothing
' ----------------------------------------------------
' Escreve no arquivo
Wscript.Echo " Pressione OK e aguarde 30 segundos "
Set strFileOpen = objFso.CreateTextFile(strPath, True)
' ----------------------------------------------------------
Set objWMI = GetObject("winmgmts:" _ 
& "{impersonationLevel=impersonate,(Security)}!\\" _  
& strComputer & "\root\cimv2") 
Set colLoggedEvents = objWMI.ExecQuery _ 
("Select * from Win32_NTLogEvent Where Logfile = 'Security' AND EventCode = '636' or EventCode = '4732'" ) 
'------------------------------------------------------------------------------------------
For Each objItem in colLoggedEvents
strFileOpen.WriteLine("Category: " & objItem.Category _
& " string " & objItem.CategoryString) 
strFileOpen.WriteLine("ComputerName: " & objItem.ComputerName)
strFileOpen.WriteLine("Data: " & objItem.TimeWritten)
strFileOpen.WriteLine("Logfile: " & objItem.Logfile _ 
& " source " & objItem.SourceName) 
strFileOpen.WriteLine("EventCode: " & objItem.EventCode) 
strFileOpen.WriteLine("EventType: " & objItem.EventType) 
strFileOpen.WriteLine("Type: " & objItem.Type) 
strFileOpen.WriteLine("User: " & objItem.User) 
strFileOpen.WriteLine("Message: " & objItem.Message)
strFileOpen.WriteLine (" ")
intRecordNum = intRecordNum +1
Next
'Confirma se o script foi concluído e abre o arquivo
Set objShell = CreateObject("WScript.Shell")
objShell.run ("Explorer" &" " & strPath & "\" )
'-------------------------------------------------------------------
WScript.Quit




Nenhum comentário:

ECAD - Executar Como Administrador

Vamos lhe mostrar um script que tem uma grande utilidade no ambiente de trabalho dos Técnicos de Apoio ao Usuário. O objetivo desse script é executar algumas tarefas com privilégios administrativos. 

Obs. (Excelente ferramenta para quem tem Windows XP com as versões do IE atualizado e impede abrir o IE no modo "Executar Como" 

Veja o Script aqui:

'========================================================================
' LINGUAGEM: VBScript'
' NAME: ECAD' VERSÃO: 1.0
' AUTHOR: DICAS QUE FUNFA
' DATE : 10/10/2011
' by: http://dicasquefunfa.com.br
'========================================================================
Option Explicit

Dim objmenu, username, wshshell, fso
Set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")

Username = InputBox("Entre com sua conta de Administrador (ex: Admin)", "ECAD - EXECUTAR COMO Admin - by Dicas Qeu Funfa v1")
Set objmenu = New gui_menu
objmenu.getInput

Class gui_menu
private Input, quit, strText, cmd, arrMenu, i, return, strProg, strComputer

Private Sub pickInput
Select Case Input

Case "1"
cmd = " ""%windir%\explorer.exe /separate"""
startProg cmd
getInput

Case "2"
cmd = " ""mmc %windir%\system32\lusrmgr.msc"""
startProg cmd
getInput

Case "3"
cmd = " ""mmc %windir%\system32\services.msc"""
startProg cmd
getInput

Case "4"
cmd = " %comspec%"
startProg cmd
getInput

Case "5"
cmd = " ""mmc %windir%\system32\compmgmt.msc"""
startProg cmd
getInput


Case "6"
cmd = " ""mmc %windir%\system32\devmgmt.msc"""
startProg cmd
getInput

Case "7"
strProg = InputBox("Digite o caminho completo para o programa desejado (ex:C:\WINDOWS\NOTEPAD.EXE) ", "Abri outro programa")
If fso.FileExists(strProg) then
cmd = " """ & strProg & """"
startProg cmd
getInput
Else
strProg = MsgBox("O arquivo não existi, tente novamente!",48,"Error!!")
getInput
End if

Case "8"
strComputer = InputBox("Digite o nome do computador Windows XP para ativar o remote desktop")

Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colServiceList = objWMIService.ExecQuery _
        ("Select * from Win32_Service where Name='TermService'")
For each objService in colServiceList
    errReturn = objService.StopService()
Next

Set colTSSettings = objWMIService.InstancesOf("Win32_TerminalServiceSetting")

For Each colTS in colTSSettings
 colTS.SetAllowTSConnections(1)
Next

Set colServiceList = objWMIService.ExecQuery _
        ("Select * from Win32_Service where Name='TermService'")
For each objService in colServiceList
    errReturn = objService.StartService()
Next

Case "9"
quit = MsgBox ("Você realmente deseja sair?", 36, "Deseja Sair?")'52
If quit = 6 Then
MsgBox ("Dicas Que Funfa lhe deseja um Excelente trabalho!!")
WScript.Quit
Else
getInput
End If

Case ""
quit = MsgBox ("Você realmente deseja sair?", 36, "Deseja Sair?")'52
If quit = 6 Then
MsgBox ("Dicas Que Funfa lhe deseja um Excelente trabalho!!")
WScript.Quit
Else
getInput
End If

Case Else
MsgBox ("Hum! Essa é uma entrada incorreta, tente outra!")
getInput
End Select
End Sub 'pickInput

Public sub getInput
arrMenu = Array("Para Abrir o Explorer","Para abrir Usuários e grupos locais","Para Serviços","Abre o Prompt de Comando","Aqui vai abrir o Gerenciamento do computador","Esse abre o Gerenciador de dispositivos","Aqui você escolhe o que deseja Abrir", "Ativa o Acesso Remoto","Aqui você vai Sair")
strText = "Escolha umas das opções abaixo." & vbNewLine

For i = 1 To (UBound(arrMenu) + 1)
strText = strText & i & " - " & arrMenu(i - 1) & vbNewLine
Next
Input = InputBox(strText, "Escola uma das opções")
pickInput
End sub 'getInput

Private Sub startProg(cmd)
return = WshShell.Run("%windir%\system32\runas.exe /user:SEU_DOMINIO_AQUI\" & username & cmd, 1, False)
End Sub 'startProg
End Class 'gui_menu

Vide exemplo do script em execução

 
1. Entre com sua conta de Administrador (se sua conta for no AD, não precisa informar o domínio aqui. Ele deve ser informado na linha 144 onde está escrito: return = WshShell.Run("%windir%\system32\runas.exe /user:SEU_DOMINIO_AQUI\" & username & cmd, 1, False)
  )
 
2. Escolha uma das opções 

3. Informe sua senha para abrir o programa desejado

Você pode fazer suas personalizações conforme suas necessidades.


Nenhum comentário:

Marcadores

3G Modem Access Acesso Remoto ACT Active Directory ADOBE Adware Agendador de Tarefas Android Android Studio Antivírus App Apple AppXPackage Área de Trabalho Remota Atalhos de teclado AutoCAD BIOS Bitcoin Boa Dica Boot BSOD CentOS Certificação Cisco Citrix CLARO CMD CMS Codec Compatibilidade Concurso CorelDRAW CSS Curiosidade Curso Grátis Database Debian Desenvolvimento Dica Dicas Windows 8 Download Driver DUMP eBooks Excel Facebook Ferramentas Firefox Flash Flutter FTP Game Good tip Google Google Chrome Google Cloud HP HTML HTML5 Hype-V IBM Sametime Impressora Internet Internet Explorer iOS iPad iPhone ISO ITIL Java Kali Linux KB keyboard shortcuts Kindle Leitora Biométrica LibreOffice Linux Lotus Notes MAC (Media Access Control) MAC OS X Malwares MariaDB Microsoft Edge Modem Modem 3G Mozilla Firefox MSI MSTSC MySQL Notebook Notícias ODBC Office 2003 Office 2007 Office 2010 Office 2013 Office 2016 Outlook Papel de Parede PC PHP Plugin PowerPoint PowerShell Proxy Raspberry Pi RDP Redes Regedit Reset Roteador Ruby On Rails Scanner Segurança de TI Senha Smartphone Software Soluções SQL SERVER 2005 SSD Switch Tablet Thin Client Ubuntu Utilitários VBScript vCurso vDica video VMware Player WhatsApp Windows Windows 10 Windows 10 Education Windows 10 Enterprise Windows 10 Home Windows 10 IoT Windows 10 Pro Windows 7 Windows 7 Enterprise Windows 7 Home Basic Windows 7 Home Premium Windows 7 Starter Edition Windows 7 Ultimate Windows 8 Windows 8.1 Windows Phone Windows Preview Windows Server 2008 Windows Server 2012 Windows To Go Windows Update Windows Vista Windows XP Wireless WMI Word WordPress